package fx.basicusage {
    import as3.collections.fx.ISortedSetFx;
    import as3.collections.fx.SortedSetFx;
    import as3.collections.fx.events.FxEvents;
    import as3.collections.fx.events.SetEvent;
    import as3.collections.iterators.IIterator;
    import as3.collections.utils.NumericComparator;
   
    import flash.display.Sprite;
   
    public class SortedSetFxExample extends Sprite {
     
     public var theSet : ISortedSetFx;
     
     public function SortedSetFxExample() {
      
      theSet = new SortedSetFx(new NumericComparator());
      theSet.addEventListener(FxEvents.COLLECTION_CHANGED, collectionChanged);
      
      // add - [1,2,3,4]
      theSet.addItem(4);
      theSet.addItem(1);
      theSet.addItem(3); 
      theSet.addItem(2);
      
      // remove - [1]
      theSet.removeItem(2);
      theSet.removeFirstItem();
      theSet.removeLastItem();
   
      // empty theSet - []
      theSet.clear();
   
     }
     
     private function collectionChanged(event : SetEvent) : void {
      var item : = event.item;
      var iterator : IIterator = event.getIterator();
      
      switch (event.kind) {
       case FxEvents.ITEM_ADDED:
        trace ("Added item: " + item);
        trace ("Added after: " + iterator.getCurrent());
        iterator.getNext(); // returns added item
        trace ("Added before: " + iterator.getNext());
        break;
       case FxEvents.ITEM_REMOVED:
        trace ("Removed " + item);
        trace ("Removed after: " + iterator.getCurrent());
        trace ("Removed before: " + iterator.getNext());
        break;
       case FxEvents.ITEM_REPLACED:
        trace ("Replaced item: " + item);
        trace ("Replaced after: " + iterator.getCurrent());
        iterator.getNext(); // returns replaced item
        trace ("Replaced before: " + iterator.getNext());
        break;
       case FxEvents.COLLECTION_EMPTIED:
        trace ("Collection emptied");
        break;
      }
      
      trace ("----------------------");
      trace ("[" + theSet.toArray() + "]\n");
     }
    }
   }
   
   // Added item: 4
   // Added after: undefined
   // Added before: undefined
   // ----------------------
   // [4]
   
   // Added item: 1
   // Added after: undefined
   // Added before: 4
   // ----------------------
   // [1,4]
   
   // Added item: 3
   // Added after: 1
   // Added before: 4
   // ----------------------
   // [1,3,4]
   
   // Added item: 2
   // Added after: 1
   // Added before: 3
   // ----------------------
   // [1,2,3,4]
   
   // Removed 2
   // Removed after: 1
   // Removed before: 3
   // ----------------------
   // [1,3,4]
   
   // Removed 1
   // Removed after: undefined
   // Removed before: 3
   // ----------------------
   // [3,4]
   
   // Removed 4
   // Removed after: 3
   // Removed before: undefined
   // ----------------------
   // [3]
   
   // Collection emptied
   // ----------------------
   // []