package fx.basicusage {
    import as3.collections.fx.ISortedMapFx;
    import as3.collections.fx.SortedMapFx;
    import as3.collections.fx.events.FxEvents;
    import as3.collections.fx.events.MapEvent;
    import as3.collections.iterators.IMapIterator;
    import as3.collections.utils.NumericComparator;
   
    import flash.display.Sprite;
   
    public class SortedMapFxExample extends Sprite {
     
     public var map : ISortedMapFx;
     
     public function SortedMapFxExample() {
      
      map = new SortedMapFx(new NumericComparator());
      map.addEventListener(FxEvents.COLLECTION_CHANGED, collectionChanged);
      
      // add - [1,2,3,4]
      map.addItem("2", 2);
      map.addItem("4", 4);
      map.addItem("1", 1);
      map.addItem("3", 3); 
      
      // replace - [1,2,3,44]
      map.replaceItem("4", 44);
      map.replaceItem("2", 2); // no event since 2 == 2
   
      // remove - [1,44]
      map.removeKey("2");
      map.removeKey("3");
   
      // empty map - []
      map.clear();
   
     }
     
     private function collectionChanged(event : MapEvent) : void {
      var key : = event.key;
      var item : = event.item;
      var iterator : IMapIterator = event.getIterator();
      
      switch (event.kind) {
       case FxEvents.ITEM_ADDED:
        trace ("Added item: " + item + " key " + key);
        trace ("Added after: " + iterator.getCurrent() + " key " + iterator.getKey());
        iterator.getNext(); // returns added item
        trace ("Added before: " + iterator.getNext() + " key " + iterator.getKey());
        break;
       case FxEvents.ITEM_REMOVED:
        trace ("Removed " + item + " key " + key);
        trace ("Removed after: " + iterator.getCurrent() + " key " + iterator.getKey());
        trace ("Removed before: " + iterator.getNext() + " key " + iterator.getKey());
        break;
       case FxEvents.ITEM_REPLACED:
        trace ("Replaced item: " + item + " key " + key);
        trace ("Replaced after: " + iterator.getCurrent() + " key " + iterator.getKey());
        iterator.getNext(); // returns replaced item
        trace ("Replaced before: " + iterator.getNext() + " key " + iterator.getKey());
        break;
       case FxEvents.COLLECTION_EMPTIED:
        trace ("Collection emptied");
        break;
      }
      
      trace ("----------------------");
      trace ("[" + map.toArray() + "]\n");
     }
    }
   }
   
   // Added item: 2 key 2
   // Added after: undefined key undefined
   // Added before: undefined key undefined
   // ----------------------
   // [2]
   
   // Added item: 4 key 4
   // Added after: 2 key 2
   // Added before: undefined key undefined
   // ----------------------
   // [2,4]
   
   // Added item: 1 key 1
   // Added after: undefined key undefined
   // Added before: 2 key 2
   // ----------------------
   // [1,2,4]
   
   // Added item: 3 key 3
   // Added after: 2 key 2
   // Added before: 4 key 4
   // ----------------------
   // [1,2,3,4]
   
   // Removed 4 key 4
   // Removed after: 3 key 3
   // Removed before: undefined key undefined
   // ----------------------
   // [1,2,3]
   
   // Added item: 44 key 4
   // Added after: 3 key 3
   // Added before: undefined key undefined
   // ----------------------
   // [1,2,3,44]
   
   // Removed 2 key 2
   // Removed after: 1 key 1
   // Removed before: 3 key 3
   // ----------------------
   // [1,3,44]
   
   // Removed 3 key 3
   // Removed after: 1 key 1
   // Removed before: 44 key 4
   // ----------------------
   // [1,44]
   
   // Collection emptied
   // ----------------------
   // []