package fx.basicusage {
    import as3.collections.fx.ILinkedSetFx;
    import as3.collections.fx.LinkedSetFx;
    import as3.collections.fx.events.FxEvents;
    import as3.collections.fx.events.SetEvent;
    import as3.collections.iterators.IIterator;
   
    import flash.display.Sprite;
   
    public class LinkedSetFxExample extends Sprite {
     
     public var theSet : ILinkedSetFx;
     
     public function LinkedSetFxExample() {
      
      theSet = new LinkedSetFx();
      theSet.addEventListener(FxEvents.COLLECTION_CHANGED, collectionChanged);
      
      // add - [3,1,2,4]
      theSet.addItem(1);
      theSet.addItem(2);
      theSet.addItemAtEnd(4);
      theSet.addItemAtStart(3); 
      
      // remove - [1]
      theSet.removeItem(2);
      theSet.removeFirstItem();
      theSet.removeLastItem();
   
      // empty theSet - []
      theSet.clear();
   
     }
     
     private function collectionChanged(event : SetEvent) : void {
      var item : = event.item;
      var iterator : IIterator = event.getIterator();
      
      switch (event.kind) {
       case FxEvents.ITEM_ADDED:
        trace ("Added item: " + item);
        trace ("Added after: " + iterator.getCurrent());
        iterator.getNext(); // returns added item
        trace ("Added before: " + iterator.getNext());
        break;
       case FxEvents.ITEM_REMOVED:
        trace ("Removed " + item);
        trace ("Removed after: " + iterator.getCurrent());
        trace ("Removed before: " + iterator.getNext());
        break;
       case FxEvents.ITEM_REPLACED:
        trace ("Replaced item: " + item);
        trace ("Replaced after: " + iterator.getCurrent());
        iterator.getNext(); // returns replaced item
        trace ("Replaced before: " + iterator.getNext());
        break;
       case FxEvents.COLLECTION_EMPTIED:
        trace ("Collection emptied");
        break;
      }
      
      trace ("----------------------");
      trace ("[" + theSet.toArray() + "]\n");
     }
    }
   }
   
   // Added item: 1
   // Added after: undefined
   // Added before: undefined
   // ----------------------
   // [1]
   
   // Added item: 2
   // Added after: 1
   // Added before: undefined
   // ----------------------
   // [1,2]
   
   // Added item: 4
   // Added after: 2
   // Added before: undefined
   // ----------------------
   // [1,2,4]
   
   // Added item: 3
   // Added after: undefined
   // Added before: 1
   // ----------------------
   // [3,1,2,4]
   
   // Removed 2
   // Removed after: 1
   // Removed before: 4
   // ----------------------
   // [3,1,4]
   
   // Removed 3
   // Removed after: undefined
   // Removed before: 1
   // ----------------------
   // [1,4]
   
   // Removed 4
   // Removed after: 1
   // Removed before: undefined
   // ----------------------
   // [1]
   
   // Collection emptied
   // ----------------------
   // []