package fx.basicusage {
    import as3.collections.fx.ILinkedMapFx;
    import as3.collections.fx.LinkedMapFx;
    import as3.collections.fx.events.FxEvents;
    import as3.collections.fx.events.MapEvent;
    import as3.collections.iterators.IMapIterator;
   
    import flash.display.Sprite;
   
    public class LinkedMapFxExample extends Sprite {
     
     public var map : ILinkedMapFx;
     
     public function LinkedMapFxExample() {
      
      map = new LinkedMapFx();
      map.addEventListener(FxEvents.COLLECTION_CHANGED, collectionChanged);
      
      // add - [3,1,2,4]
      map.addItem("1", 1);
      map.addItem("2", 2);
      map.addItemAtEnd("4", 4);
      map.addItemAtStart("3", 3); 
      
      // replace - [3,1,2,44]
      map.replaceItem("4", 44);
      map.replaceItem("2", 2); // no event since 2 == 2
   
      // remove - [1]
      map.removeKey("2");
      map.removeFirstItem();
      map.removeLastItem();
   
      // empty map - []
      map.clear();
   
     }
     
     private function collectionChanged(event : MapEvent) : void {
      var key : = event.key;
      var item : = event.item;
      var iterator : IMapIterator = event.getIterator();
      
      switch (event.kind) {
       case FxEvents.ITEM_ADDED:
        trace ("Added item: " + item + " key " + key);
        trace ("Added after: " + iterator.getCurrent() + " key " + iterator.getKey());
        iterator.getNext(); // returns added item
        trace ("Added before: " + iterator.getNext() + " key " + iterator.getKey());
        break;
       case FxEvents.ITEM_REMOVED:
        trace ("Removed " + item + " key " + key);
        trace ("Removed after: " + iterator.getCurrent() + " key " + iterator.getKey());
        trace ("Removed before: " + iterator.getNext() + " key " + iterator.getKey());
        break;
       case FxEvents.ITEM_REPLACED:
        trace ("Replaced item: " + item + " key " + key);
        trace ("Replaced after: " + iterator.getCurrent() + " key " + iterator.getKey());
        iterator.getNext(); // returns replaced item
        trace ("Replaced before: " + iterator.getNext() + " key " + iterator.getKey());
        break;
       case FxEvents.COLLECTION_EMPTIED:
        trace ("Collection emptied");
        break;
      }
      
      trace ("----------------------");
      trace ("[" + map.toArray() + "]\n");
     }
    }
   }
   
   // Added item: 1 key 1
   // Added after: undefined key undefined
   // Added before: undefined key undefined
   // ----------------------
   // [1]
   
   // Added item: 2 key 2
   // Added after: 1 key 1
   // Added before: undefined key undefined
   // ----------------------
   // [1,2]
   
   // Added item: 4 key 4
   // Added after: 2 key 2
   // Added before: undefined key undefined
   // ----------------------
   // [1,2,4]
   
   // Added item: 3 key 3
   // Added after: undefined key undefined
   // Added before: 1 key 1
   // ----------------------
   // [3,1,2,4]
   
   // Replaced item: 44 key 4
   // Replaced after: 2 key 2
   // Replaced before: undefined key undefined
   // ----------------------
   // [3,1,2,44]
   
   // Removed 2 key 2
   // Removed after: 1 key 1
   // Removed before: 44 key 4
   // ----------------------
   // [3,1,44]
   
   // Removed 3 key 3
   // Removed after: undefined key undefined
   // Removed before: 1 key 1
   // ----------------------
   // [1,44]
   
   // Removed 44 key 4
   // Removed after: 1 key 1
   // Removed before: undefined key undefined
   // ----------------------
   // [1]
   
   // Collection emptied
   // ----------------------
   // []