package fx.basicusage {
    import as3.collections.fx.ArrayListFx;
    import as3.collections.fx.IArrayListFx;
    import as3.collections.fx.events.ArrayListEvent;
    import as3.collections.fx.events.FxEvents;
    import as3.collections.iterators.IIterator;
   
    import flash.display.Sprite;
   
    public class ArrayListFxExample extends Sprite {
     
     public var list : IArrayListFx;
     
     public function ArrayListFxExample() {
      
      list = new ArrayListFx();
      list.addEventListener(FxEvents.COLLECTION_CHANGED, collectionChanged);
      
      // add - [5,1,3,2,4]
      list.addItem(1);
      list.addItem(2);
      list.addItemAt(1, 3);
      list.addItemAtEnd(4);
      list.addItemAtStart(5); 
      
      // replace - [5,1,3,2,3]
      list.replaceItemAt(4, 3);
      list.replaceItemAt(3, 2); // no event since 2 == 2
   
      // remove - [1]
      list.removeItem(2);
      list.removeItemAt(0);
      list.removeAll(3);
   
      // change source - [1,2,3,4,5]
      list.setArray([1,2,3,4,5]);
   
      // empty list - []
      list.clear();
   
     }
     
     private function collectionChanged(event : ArrayListEvent) : void {
      var item : = event.item;
      var index : = event.index;
      var iterator : IIterator = event.getIterator();
      
      switch (event.kind) {
       case FxEvents.ITEM_ADDED:
        trace ("Added item: " + item + " at index " + index);
        trace ("Added after: " + iterator.getCurrent());
        iterator.getNext(); // returns added item
        trace ("Added before: " + iterator.getNext());
        break;
       case FxEvents.ITEM_REMOVED:
        trace ("Removed " + item + " at index " + index);
        trace ("Removed after: " + iterator.getCurrent());
        trace ("Removed before: " + iterator.getNext());
        break;
       case FxEvents.ITEM_REPLACED:
        trace ("Replaced item: " + item + " at index " + index);
        trace ("Replaced after: " + iterator.getCurrent());
        iterator.getNext(); // returns replaced item
        trace ("Replaced before: " + iterator.getNext());
        break;
       case FxEvents.COLLECTION_REPLACED:
        trace ("Collection replaced");
        break;
       case FxEvents.COLLECTION_EMPTIED:
        trace ("Collection emptied");
        break;
      }
      
      trace ("----------------------");
      trace ("[" + list.toArray() + "]\n");
     }
    }
   }
   
   // Added item: 1 at index 0
   // Added after: undefined
   // Added before: undefined
   // ----------------------
   // [1]
   
   // Added item: 2 at index 1
   // Added after: 1
   // Added before: undefined
   // ----------------------
   // [1,2]
   
   // Added item: 3 at index 1
   // Added after: 1
   // Added before: 2
   // ----------------------
   // [1,3,2]
   
   // Added item: 4 at index 3
   // Added after: 2
   // Added before: undefined
   // ----------------------
   // [1,3,2,4]
   
   // Added item: 5 at index 0
   // Added after: undefined
   // Added before: 1
   // ----------------------
   // [5,1,3,2,4]
   
   // Replaced item: 3 at index 4
   // Replaced after: 2
   // Replaced before: undefined
   // ----------------------
   // [5,1,3,2,3]
   
   // Removed 2 at index 3
   // Removed after: 3
   // Removed before: 3
   // ----------------------
   // [5,1,3,3]
   
   // Removed 3 at index 1
   // Removed after: 1
   // Removed before: 3
   // ----------------------
   // [1,3]
   
   // Removed 3 at index 1
   // Removed after: 1
   // Removed before: undefined
   // ----------------------
   // [1]
   
   // Collection replaced
   // ----------------------
   // [1,2,3,4,5]
   
   // Collection emptied
   // ----------------------
   // []